package scientific.stats.continuous

import std.math.*
import std.unittest.*
import std.unittest.testmacro.*

import scientific.numbers.*
import scientific.stats.random.*

/*
 * Log of Probability density function
 */
public func genexponLogPDF(x: Float64, a: Float64, b: Float64, c: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (y < 0.0) {
        throw IllegalArgumentException("genexponLogPDF: input value x out of bound.")
    }

    if (a <= 0.0 || b <= 0.0 || c <= 0.0) {
        throw IllegalArgumentException("genexponLogPDF: shape parameter out of bound.")
    }

    let temp = b / c * (1.0 - exp(-c * y))
    return log(a + temp * c) - a * y - b * y + temp - log(scale)
}

/*
 * Probability density function
 */
public func genexponPDF(x: Float64, a: Float64, b: Float64, c: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (y < 0.0) {
        throw IllegalArgumentException("genexponPDF: input value x out of bound.")
    }

    if (a <= 0.0 || b <= 0.0 || c <= 0.0) {
        throw IllegalArgumentException("genexponPDF: shape parameter out of bound.")
    }

    return exp(genexponLogPDF(x, a, b, c, loc: loc, scale: scale))
}

/*
 * Cumulative probability density function
 */
public func genexponCDF(x: Float64, a: Float64, b: Float64, c: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (y < 0.0) {
        throw IllegalArgumentException("genexponCDF: input value x out of bound.")
    }

    if (a <= 0.0 || b <= 0.0 || c <= 0.0) {
        throw IllegalArgumentException("genexponCDF: shape parameter out of bound.")
    }
    
    let temp = b * (-exp(-c * y) + 1.0) / c
    let t = (-a - b) * y + temp
    return 1.0 - exp(t)
}

/*
 * Log of Cumulative probability density function
 */
public func genexponLogCDF(x: Float64, a: Float64, b: Float64, c: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (y < 0.0) {
        throw IllegalArgumentException("genexponLogCDF: input value x out of bound.")
    }

    if (a <= 0.0 || b <= 0.0 || c <= 0.0) {
        throw IllegalArgumentException("genexponLogCDF: shape parameter out of bound.")
    }

    let temp = genexponCDF(x, a, b, c, loc: loc, scale: scale)
    if (temp < 0.000001) {
        throw IllegalArgumentException("genlogisticCDF: return-value too small.")
    }
    return log(temp)
}

@Test
public class TestGenexpon {
    @TestCase
    func testGenexpon(): Unit {
        @Assert(approxEqual(genexponLogPDF(2.0, 2.0, 2.0, 2.0, loc: 1.0, scale: 2.0), -0.8779993155266924, atol:1e-13))
        @Assert(approxEqual(genexponLogCDF(2.0, 2.0, 2.0, 2.0, loc: 1.0, scale: 2.0), -0.2938965155572696, atol:1e-13)) 
    }
}