package scientific.stats.continuous

import std.math.*
import std.unittest.*
import std.unittest.testmacro.*

import scientific.numbers.*
import scientific.stats.random.*

/*
 * Log of Probability density function
 */
public func gompertzLogPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("gompertzLogPDF: shape parameter out of bound.")
    }

    if (y < 0.0) {
        throw IllegalArgumentException("gompertzLogPDF: input value out of bound.")
    }

    return log(k) + y - k * (exp(y) - 1.0) - log(scale)
}

/*
 * Probability density function
 */
public func gompertzPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("gompertzPDF: shape parameter out of bound.")
    }

    if (y < 0.0) {
        throw IllegalArgumentException("gompertzPDF: input value out of bound.")
    }

    return exp(gompertzLogPDF(x, k, loc: loc, scale: scale))
}

/*
 * Cumulative probability density function
 */
public func gompertzCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("gompertzCDF: shape parameter out of bound.")
    }

    if (y < 0.0) {
        throw IllegalArgumentException("gompertzCDF: input value out of bound.")
    }

    let temp = k - k * exp(y)
    return 1.0 - exp(temp)
}

/*
 * Log of Cumulative probability density function
 */
public func gompertzLogCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("gompertzLogCDF: shape parameter out of bound.")
    }

    if (y < 0.0) {
        throw IllegalArgumentException("gompertzLogCDF: input value out of bound.")
    }

    let temp = gompertzCDF(x, k, loc: loc, scale: scale)
    if (temp < 0.000001) {
        throw IllegalArgumentException("gompertzLogCDF: return-value too small.")
    }

    return log(temp) 
}


/*
 * ppf
 */
public func gompertzPPF(q: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    if (q <= 0.0 || q >= 1.0) {
        throw IllegalArgumentException("gompertzPPF: quantile out of bound.")
    }

    if (k <= 0.0) {
        throw IllegalArgumentException("gompertzPPF: shape parameter out of bound.")
    }

    let t = 1.0 / k * log(1.0 - q)
    let res = log(1.0 - t)
    return res * scale + loc
}


@Test
public class TestGompertz {
    @TestCase
    func testGompertz(): Unit {
        @Assert(approxEqual(gompertzLogPDF(2.0, 2.0, loc: 1.0, scale: 2.0), -0.7974425414002563, atol:1e-13))
        @Assert(approxEqual(gompertzLogCDF(2.0, 2.0, loc: 1.0, scale: 2.0), -0.3191447713509225, atol:1e-13)) 
        @Assert(approxEqual(gompertzPPF(0.2, 2.0, loc: 1.0, scale: 2.0),     1.21155005565436,   atol:1e-13)) 
    }
}