package scientific.stats.continuous

import std.math.*
import std.unittest.*
import std.unittest.testmacro.*

import scientific.numbers.*
import scientific.stats.random.*

/*
 * Log of Probability density function
 */
public func halfcauchyLogPDF(x: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale   

    if (y < 0.0) {
        throw IllegalArgumentException("halfcauchyLogPDF: input value out of bound.")
    }

    let res = log(2.0) - log(Float64.getPI()) - log(1.0 + y * y)
    return res - log(scale)
}

/*
 * Probability density function
 */
public func halfcauchyPDF(x: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (y < 0.0) {
        throw IllegalArgumentException("halfcauchyPDF: input value out of bound.")
    }

    let temp = halfcauchyLogPDF(x, loc: loc, scale: scale)
    return exp(temp)
}

/*
 * Cumulative probability density function
 */
public func halfcauchyCDF(x: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (y < 0.0) {
        throw IllegalArgumentException("halfcauchyPDF: input value out of bound.")
    }

    return 2.0 / Float64.getPI() * atan(y)
}


/*
 * Cumulative probability density function
 */
public func halfcauchyLogCDF(x: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (y < 0.0) {
        throw IllegalArgumentException("halfcauchyLogCDF: input value out of bound.")
    }

    let temp = halfcauchyCDF(x, loc: loc, scale: scale)

    if (temp < 0.000001) {
        throw IllegalArgumentException("halfcauchyLogCDF: return-value too small.")
    }

    return log(temp)
}


/*
 * PPF
 */
public func halfcauchyPPF(q: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    if (q <= 0.0 || q >= 1.0) {
        throw IllegalArgumentException("halfcauchyPPF: quantile out of bound.")
    }

    let temp = 0.5 * Float64.getPI() * q
    let res = tan(temp)
    return res * scale + loc
}


/*
 * compute the mean
 */
public func halfcauchyMean(loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    return Float64.Inf
}


/*
 * compute the var
 */
public func halfcauchyVar(loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    return Float64.Inf
}

/*
 * compute the std
 */
public func halfcauchyStd(loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    return Float64.Inf
}

@Test
public class TestHalfCauchy {
    @TestCase
    func testHalfcauchy(): Unit {
        @Assert(approxEqual(halfcauchyLogPDF(3.0, loc: 2.0, scale: 1.0), -1.1447298858494002, atol:1e-13))
        @Assert(approxEqual(halfcauchyLogCDF(3.0, loc: 2.0, scale: 1.0), -0.6931471805599453, atol:1e-13))
        @Assert(approxEqual(halfcauchyPPF(0.7, loc: 2.0, scale: 1.0),     3.9626105055051504, atol:1e-13))
    }
}