package scientific.stats.continuous

import std.math.*
import std.unittest.*
import std.unittest.testmacro.*

import scientific.numbers.*
import scientific.stats.random.*

/*
 * Log of Probability density function
 */
public func invweibullLogPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("invweibullLogPDF: shape parameter out of bound.")
    }

    if (y <= 0.0) {
        throw IllegalArgumentException("invweibullLogPDF: input value out of bound.")
    }

    let temp = log(k) - (k + 1.0) * log(y) - pow(y, -k)
    return temp - log(scale)
}

/*
 * Probability density function
 */
public func invweibullPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("invweibullPDF: shape parameter out of bound.")
    }

    if (y <= 0.0) {
        throw IllegalArgumentException("invweibullPDF: input value out of bound.")
    }

    return exp(invweibullLogPDF(x, k, loc: loc, scale: scale))
}

/*
 * Cumulative probability density function
 */
public func invweibullCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("invweibullCDF: shape parameter out of bound.")
    }

    if (y <= 0.0) {
        throw IllegalArgumentException("invweibullCDF: input value out of bound.")
    }

    let t = pow(y, -k)
    let res = exp(-t)
    return res
}

/*
 * Log of Cumulative probability density function
 */
public func invweibullLogCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("invweibullLogCDF: shape parameter out of bound.")
    }

    if (y <= 0.0) {
        throw IllegalArgumentException("invweibullLogCDF: input value out of bound.")
    }

    let temp = invweibullCDF(x, k, loc:loc, scale: scale)
    if (temp < 0.000001) {
        throw IllegalArgumentException("invweibullLogCDF: return-value too small.")
    }

    return log(temp)
}


/*
 * PPF
 */
public func invweibullPPF(q: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    if (q <= 0.0 || q >= 1.0) {
        throw IllegalArgumentException("invweibullPPF: quantile out of bound.")
    }

    if (k <= 0.0) {
        throw IllegalArgumentException("invweibullLogCDF: shape parameter out of bound.")
    }

    let temp = pow(-log(q), -1.0 / k)
    return temp * scale + loc
}

@Test
public class TestInvweibull {
    @TestCase
    func testInvweibull(): Unit {
        @Assert(approxEqual(invweibullLogPDF(2.0, 2.0, loc: 1.0, scale: 2.0), -1.9205584583201643, atol:1e-13))
        @Assert(approxEqual(invweibullLogCDF(2.0, 2.0, loc: 1.0, scale: 2.0), -4.0,                atol:1e-13)) 
        @Assert(approxEqual(invweibullPPF(0.2, 2.0, loc: 1.0, scale: 2.0),     2.5764960317864576, atol:1e-13)) 
    }
}