package scientific.stats.continuous

import std.math.*
import std.unittest.*
import std.unittest.testmacro.*

import scientific.numbers.*
import scientific.stats.random.*

/*
 * Log of Probability density function
 */
public func paretoLogPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("paretoLogPDF: shape parameter out of bound.")
    }
    if (y < 1.0) {
        throw IllegalArgumentException("paretoLogPDF: input value out of bound.")
    }

    let res = log(k) - (1.0 + k) * log(y)
    return res - log(scale)
}

/*
 * Probability density function
 */
public func paretoPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("paretoPDF: shape parameter out of bound.")
    }

    if (y < 1.0) {
        throw IllegalArgumentException("paretoPDF: input value out of bound.")
    }

    return exp(paretoLogPDF(x, k, loc: loc, scale: scale))
}

/*
 * Cumulative probability density function
 */
public func paretoCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("paretoCDF: shape parameter out of bound.")
    }

    if (y < 1.0) {
        throw IllegalArgumentException("paretoCDF: input value out of bound.")
    }

    let res = 1.0 - pow(y, -k)
    return res
}

/*
 * Log of Cumulative probability density function
 */
public func paretoLogCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("paretoLogCDF: shape parameter out of bound.")
    }
    if (y < 1.0) {
        throw IllegalArgumentException("paretoLogCDF: input value out of bound.")
    }

    let temp = paretoCDF(x, k, loc:loc, scale: scale)
    if (temp < 0.000001) {
        throw IllegalArgumentException("paretoLogCDF: return-value too small.")
    }

    return log(temp)
}


/*
 * PPF
 */
public func paretoPPF(q: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    if (q <= 0.0 || q >= 1.0) {
        throw IllegalArgumentException("paretoPPF: quantile out of bound.")
    }

    if (k <= 0.0) {
        throw IllegalArgumentException("paretoPPF: shape parameter out of bound.")
    }

    let res = pow(1.0 - q, -1.0 / k)
    return res * scale + loc
}

@Test
public class TestPareto {
    @TestCase
    func testPareto(): Unit {
        @Assert(approxEqual(paretoLogPDF(4.0, 2.0, loc: 1.0, scale: 2.0), -1.2163953243244932, atol:1e-13))
        @Assert(approxEqual(paretoLogCDF(4.0, 2.0, loc: 1.0, scale: 2.0), -0.587786664902119,  atol:1e-13))
        @Assert(approxEqual(paretoPPF(0.2, 2.0, loc: 1.0, scale: 2.0),     3.23606797749979,   atol:1e-13))
    }
}