package scientific.stats.continuous

import std.math.*
import std.unittest.*
import std.unittest.testmacro.*

import scientific.numbers.*
import scientific.stats.random.*

/*
 * Log of Probability density function
 */
public func powerlawLogPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("powerlawLogPDF: shape parameter out of bound.")
    }
    if (y < 0.0 || y > 1.0) {
        throw IllegalArgumentException("powerlawLogPDF: input value out of bound.")
    }

    let res = log(k) + (k - 1.0) * log(y)
    return res - log(scale)
}

/*
 * Probability density function
 */
public func powerlawPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("powerlawPDF: shape parameter out of bound.")
    }

    if (y < 0.0 || y > 1.0) {
        throw IllegalArgumentException("powerlawPDF: input value out of bound.")
    }

    return exp(powerlawLogPDF(x, k, loc: loc, scale: scale))
}

/*
 * Cumulative probability density function
 */
public func powerlawCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("powerlawPDF: shape parameter out of bound.")
    }

    if (y < 0.0 || y > 1.0) {
        throw IllegalArgumentException("powerlawPDF: input value out of bound.")
    }

    let res = pow(y, k)
    return res
}

/*
 * Log of Cumulative probability density function
 */
public func powerlawLogCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("powerlawLogCDF: shape parameter out of bound.")
    }
    if (y < 0.0 || y > 1.0) {
        throw IllegalArgumentException("powerlawLogCDF: input value out of bound.")
    }

    let temp = powerlawCDF(x, k, loc:loc, scale: scale)
    if (temp < 0.000001) {
        throw IllegalArgumentException("powerlawLogCDF: return-value too small.")
    }

    return log(temp)
}


/*
 * PPF
 */
public func powerlawPPF(q: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    if (q <= 0.0 || q >= 1.0) {
        throw IllegalArgumentException("powerlawPPF: quantile out of bound.")
    }

    if (k <= 0.0) {
        throw IllegalArgumentException("powerlawPPF: shape parameter out of bound.")
    }

    let res = pow(q, 1.0 / k)
    return res * scale + loc
}

@Test
public class TestPowerlaw {
    @TestCase
    func testPowerlaw(): Unit {
        @Assert(approxEqual(powerlawLogPDF(1.5, 2.0, loc: 1.0, scale: 2.0), -1.3862943611198906, atol:1e-13))
        @Assert(approxEqual(powerlawLogCDF(1.5, 2.0, loc: 1.0, scale: 2.0), -2.772588722239781,  atol:1e-13))
        @Assert(approxEqual(powerlawPPF(0.2, 2.0, loc: 1.0, scale: 2.0),     1.8944271909999157, atol:1e-13))
    }
}