package scientific.stats.continuous

import std.math.*
import std.unittest.*
import std.unittest.testmacro.*

import scientific.numbers.*
import scientific.stats.normal.*
import scientific.stats.random.*

/*
 * Log of Probability density function
 */
public func powernormLogPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("powernormLogPDF: shape parameter out of bound.")
    }
    if (y < 0.0) {
        throw IllegalArgumentException("powernormLogPDF: input value out of bound.")
    }

    let res = log(k) + log(normalPDF(y)) + (k - 1.0) * log(normalCDF(-y))
    return res - log(scale)
}

/*
 * Probability density function
 */
public func powernormPDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("powernormPDF: shape parameter out of bound.")
    }

    if (y < 0.0) {
        throw IllegalArgumentException("powernormPDF: input value out of bound.")
    }

    return exp(powernormLogPDF(x, k, loc: loc, scale: scale))
}

/*
 * Cumulative probability density function
 */
public func powernormCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("powernormPDF: shape parameter out of bound.")
    }

    if (y < 0.0) {
        throw IllegalArgumentException("powernormPDF: input value out of bound.")
    }

    let res = 1.0 - pow(normalCDF(-y), k)
    return res
}

/*
 * Log of Cumulative probability density function
 */
public func powernormLogCDF(x: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    let y = (x - loc) / scale

    if (k <= 0.0) {
        throw IllegalArgumentException("powernormLogCDF: shape parameter out of bound.")
    }
    if (y < 0.0) {
        throw IllegalArgumentException("powernormLogCDF: input value out of bound.")
    }

    let temp = powernormCDF(x, k, loc:loc, scale: scale)
    if (temp < 0.000001) {
        throw IllegalArgumentException("powernormLogCDF: return-value too small.")
    }

    return log(temp)
}


/*
 * PPF
 */
public func powernormPPF(q: Float64, k: Float64, loc!: Float64 = 0.0, scale!: Float64 = 1.0): Float64 {
    if (q <= 0.0 || q >= 1.0) {
        throw IllegalArgumentException("powernormPPF: quantile out of bound.")
    }

    if (k <= 0.0) {
        throw IllegalArgumentException("powernormPPF: shape parameter out of bound.")
    }

    let res = -normalPPF(pow(1.0 - q, 1.0 / k))
    return res * scale + loc
}

@Test
public class TestPowernorm {
    @TestCase
    func testPowernorm(): Unit {
        @Assert(approxEqual(powernormLogPDF(2.0, 2.0, loc: 1.0, scale: 2.0), -2.2198502947982917, atol:1e-13))
        @Assert(approxEqual(powernormLogCDF(2.0, 2.0, loc: 1.0, scale: 2.0), -0.1000362843468024, atol:1e-13))
        @Assert(approxEqual(powernormPPF(0.2, 2.0, loc: 1.0, scale: 2.0),    -1.5008429820013953, atol:1e-6))
    }
}