# Copyright (c) Huawei Technologies Co., Ltd. 2026-2026. All rights reserved.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/arkui/ace_engine/ace_config.gni")

libhilog_dirs = "//foundation/filemanagement/file_api/utils/filemgmt_libhilog"
libn_dirs = "//foundation/filemanagement/file_api/utils/filemgmt_libn"
utils_dirs = "//foundation/filemanagement/file_api/utils"
libn_src = [
  "$libn_dirs/src/n_async/n_async_work_callback.cpp",
  "$libn_dirs/src/n_async/n_async_work_promise.cpp",
  "$libn_dirs/src/n_async/n_ref.cpp",
  "$libn_dirs/src/n_class.cpp",
  "$libn_dirs/src/n_error.cpp",
  "$libn_dirs/src/n_func_arg.cpp",
  "$libn_dirs/src/n_val.cpp",
]

plugin_storage_statistics_dirs = "//plugins/file/storage_statistics"

template("plugin_storage_statistics_static") {
  forward_variables_from(invoker, "*")

  ohos_source_set(target_name) {
    platform = invoker.platform
    defines += invoker.defines
    cflags_cc += invoker.cflags_cc

    use_exceptions = true

    configs = [ "//foundation/appframework/ability/ability_runtime/cross_platform/interfaces/kits/native/appkit:appkit_native_config" ]

    include_dirs = [
      "$plugin_storage_statistics_dirs/src",
      "$libhilog_dirs",
      "$libn_dirs/include",
      "$libn_dirs/include/n_async",
      "$utils_dirs/common/include",
    ]

    sources = libn_src
    sources += [
      "$plugin_storage_statistics_dirs/src/storage_statistics_n_exporter.cpp",
      "$plugin_storage_statistics_dirs/src/storage_statistics_napi.cpp",
    ]

    deps = [
      "//base/hiviewdfx/hilog/interfaces/native/innerkits:libhilog_${target_os}",
      "//plugins/interfaces/native:plugin_log",
      "//plugins/libs/napi:napi_${target_os}",
      "//plugins/libs/uv:uv_${target_os}",
    ]

    if (platform == "android") {
      deps += [
        "./android:storage_statistics_android_jni",
        "//plugins/interfaces/native:ace_plugin_util_${target_os}",
      ]
    } else if (platform == "ios") {
      sources += [ "$plugin_storage_statistics_dirs/ios/storage_statistics_platform_helper.mm" ]
      cflags_objc = [
        "-fvisibility=default",
        "-fobjc-arc",
        "-fobjc-weak",
        "-O2",
      ]
      cflags_objcc = cflags_objc
    }

    subsystem_name = "plugins"
    part_name = "file_storage_statistics"
  }
}

foreach(item, ace_platforms) {
  plugin_storage_statistics_static("file_storage_statistics_static_" + item.name) {
    defines = []
    cflags_cc = []
    config = {
    }

    if (defined(item.config)) {
      config = item.config
    }

    if (defined(config.defines)) {
      defines = config.defines
    }

    if (defined(config.cflags_cc)) {
      cflags_cc = config.cflags_cc
    }

    platform = item.name
  }
}