# Copyright (c) 2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/arkui/ace_engine/ace_config.gni")

template("plugin_util_static") {
  forward_variables_from(invoker, "*")

  config("util_plugin_config") {
    include_dirs = [ "plugin/include" ]
    if (target_os == "android") {
      include_dirs += [ "plugin/android/java/jni" ]
    }
  }

  ohos_source_set(target_name) {
    defines += invoker.defines
    cflags_cc += invoker.cflags_cc

    include_dirs = [ "include" ]

    sources = [ "plugin/framework/util_plugin.cpp" ]

    deps = [ "//commonlibrary/ets_utils/js_util_module/util:util_static" ]
    if (target_os == "android") {
      include_dirs += [ "plugin/android/java/jni" ]
      defines += [ "ANDROID_PLATFORM" ]
      deps += [ "plugin/android/java:util_plugin_android_jni" ]
    } else if (target_os == "ios") {
      defines += [ "IOS_PLATFORM" ]
      deps += [ "plugin/ios:util_plugin_ios" ]
    }

    subsystem_name = "plugins"
    part_name = "ets_utils"
  }
}

foreach(item, ace_platforms) {
  plugin_util_static("util_static_" + item.name) {
    defines = []
    cflags_cc = []
    config = {
    }

    if (defined(item.config)) {
      config = item.config
    }

    if (defined(config.defines)) {
      defines = config.defines
    }

    if (defined(config.cflags_cc)) {
      cflags_cc = config.cflags_cc
    }
  }
}