# Copyright (c) 2025 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//plugins/vibrator/vibrator.gni")

template("plugin_vibrator_static") {
  forward_variables_from(invoker, "*")

  ohos_source_set(target_name) {
    defines += invoker.defines
    cflags_cc += invoker.cflags_cc

    include_dirs = vibrator_include
    sources = vibrator_source

    deps = [
      "//base/hiviewdfx/hilog/interfaces/native/innerkits:libhilog_${platform}",
      "//foundation/appframework/ability/ability_runtime/cross_platform/frameworks/native/base/event_handler:cross_platform_event_handler",
      "//plugins/interfaces/native:ace_plugin_util_${platform}",
      "//plugins/interfaces/native:plugin_log",
      "//plugins/libs/napi:napi_${target_os}",
      "//commonlibrary/c_utils/base:utilsbase",
    ]

    if (platform == "android") {
      include_dirs += [
        "//plugins/vibrator/frameworks/android",
        "//plugins/vibrator/frameworks/android/java/jni",
        "//plugins/vibrator/frameworks/adapter",
      ]
      defines += [ "ANDROID_PLATFORM" ]
      deps += [
        "//plugins/vibrator/frameworks/android/java:vibrator_plugin_android_jni",
      ]
    } else if (platform == "ios") {
      include_dirs += [
        "//plugins/vibrator/frameworks/ios/include",
        "//plugins/vibrator/frameworks/adapter",
      ]
      defines += [ "IOS_PLATFORM" ]
      deps += [
        "//plugins/vibrator/frameworks/ios:vibrator_ios",
      ]
    }

    subsystem_name = "plugins"
    part_name = "vibrator"
  }
}

foreach(item, ace_platforms) {
  plugin_vibrator_static("vibrator_static_" + item.name) {
    platform = item.name

    defines = []
    cflags_cc = []
    config = {
    }

    if (defined(item.config)) {
      config = item.config
    }

    if (defined(config.defines)) {
      defines = config.defines
    }

    if (defined(config.cflags_cc)) {
      cflags_cc = config.cflags_cc
    }
  }
}