# Copyright (c) 2024 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/arkui/ace_engine/ace_config.gni")

template("plugin_wifi_manager_static") {
  forward_variables_from(invoker, "*")

  ohos_source_set(target_name) {
    defines += invoker.defines
    cflags_cc += invoker.cflags_cc
    include_dirs = []

    sources = [
      "wifi_callback.cpp",
      "wifi_napi_device.cpp",
      "wifi_napi_entry.cpp",
      "wifi_napi_errcode.cpp",
      "wifi_napi_utils.cpp",
    ]

    deps = [ "//plugins/interfaces/native:ace_plugin_util_${platform}" ]

    if (platform == "android") {
      deps += [ "android/java:wifi_manager_android_jni" ]
    } else if (platform == "ios") {
      deps += [ "ios:wifi_manager_ios" ]
    }

    subsystem_name = "plugins"
    part_name = "wifi_manager"
  }
}

foreach(item, ace_platforms) {
  plugin_wifi_manager_static("wifi_manager_static_" + item.name) {
    platform = item.name

    defines = []
    cflags_cc = []
    config = {
    }

    if (defined(item.config)) {
      config = item.config
    }

    if (defined(config.defines)) {
      defines = config.defines
    }

    if (defined(config.cflags_cc)) {
      cflags_cc = config.cflags_cc
    }
  }
}