# Copyright 2023 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//extensions/buildflags/buildflags.gni")

assert(enable_extensions)

source_set("controlled_frame") {
  sources = [
    "api/controlled_frame_internal_api.cc",
    "api/controlled_frame_internal_api.h",
    "controlled_frame_extensions_browser_api_provider.cc",
    "controlled_frame_extensions_browser_api_provider.h",
    "controlled_frame_menu_icon_loader.cc",
    "controlled_frame_menu_icon_loader.h",
    "controlled_frame_user_agent_util.cc",
    "controlled_frame_user_agent_util.h",
  ]

  deps = [
    "//base",
    "//chrome/browser/extensions",
    "//chrome/browser/web_applications",
    "//chrome/common/controlled_frame/api",
    "//components/embedder_support:user_agent",
    "//components/guest_view/browser",
    "//content/public/common",
    "//extensions/browser",
    "//extensions/common",
    "//ui/gfx",
  ]

  configs += [
    "//build/config:precompiled_headers",
    "//build/config/compiler:wexit_time_destructors",
  ]

  public_deps = [ "//chrome/browser/controlled_frame/api:api_registration" ]
}

source_set("media_access_handler") {
  sources = [ "controlled_frame_media_access_handler.h" ]
  public_deps = [ "//chrome/browser/media:access_handler" ]
}

source_set("media_access_handler_impl") {
  sources = [ "controlled_frame_media_access_handler.cc" ]
  public_deps = [ "//chrome/browser/media:access_handler" ]
  deps = [
    ":media_access_handler",
    "//chrome/browser/media/webrtc",
    "//chrome/browser/profiles:profile",
    "//extensions/browser",
  ]
}

source_set("test_support") {
  testonly = true

  # Required by browser_test.h
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

  sources = [
    "controlled_frame_permission_request_test_base.cc",
    "controlled_frame_permission_request_test_base.h",
    "controlled_frame_test_base.cc",
    "controlled_frame_test_base.h",
  ]

  deps = [
    "//base",
    "//base/version_info",
    "//chrome/browser",
    "//chrome/browser/content_settings:content_settings_factory",
    "//chrome/browser/preloading:test_support",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/web_applications",
    "//chrome/browser/web_applications:web_applications_test_support",
    "//chrome/common:chrome_features",
    "//chrome/test:test_support",
    "//components/content_settings/core/browser",
    "//components/content_settings/core/common",
    "//content/public/browser",
    "//content/public/common",
    "//content/test:test_support",
    "//extensions/browser",
    "//testing/gmock",
    "//testing/gtest",
    "//url",
  ]

  # TODO(crbug.com/40031409): Fix code that adds exit-time destructors and
  # enable the diagnostic by removing this line.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]
}