# Copyright (c) 2024 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/ability/ability_runtime/ability_runtime.gni")

config("child_process_ndk_config") {
  include_dirs =
      [ "${ability_runtime_ndk_path}/ability/ability_runtime/child_process" ]

  if (target_cpu == "arm") {
    cflags = [ "-DBINDER_IPC_32BIT" ]
  }
}

ohos_shared_library("child_process") {
  use_exceptions = true
  sanitize = {
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    cfi_vcall_icall_only = true
    cfi_policy = "adaptive"
    debug = false
  }
  branch_protector_ret = "pac_ret"

  include_dirs = [ "include" ]

  configs = [
    "${ability_runtime_services_path}/common:common_config",
    "${ability_runtime_services_path}/common:optimize_config",
  ]
  public_configs = [ ":child_process_ndk_config" ]

  sources = [ "${ability_runtime_native_path}/child_process/src/child_callback_manager.cpp" ]

  deps = [
    "${ability_runtime_innerkits_path}/app_manager:app_manager",
    "${ability_runtime_innerkits_path}/runtime:runtime",
    "${ability_runtime_native_path}/ability/native:ability_business_error",
  ]

  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
    "ipc:ipc_capi",
    "ipc:ipc_core",
  ]

  if (ability_runtime_child_process) {
    sources += [
      "${ability_runtime_native_path}/child_process/src/native_child_callback.cpp",
      "${ability_runtime_native_path}/child_process/src/native_child_process.cpp",
    ]
    deps += [ "${ability_runtime_innerkits_path}/child_process_manager:child_process_manager" ]
  }

  output_extension = "so"
  innerapi_tags = [ "ndk" ]
  install_images = [ "system" ]
  subsystem_name = "ability"
  part_name = "ability_runtime"
  version_script = "child_process.version_script"
}