# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/ability/ability_runtime/ability_runtime.gni")

ohos_prebuilt_etc("quick_fix.cfg") {
  relative_install_dir = "init"
  source = "quick_fix.cfg"
  part_name = "ability_runtime"
  subsystem_name = "ability"
}

config("quickfixms_config") {
  visibility = [ ":*" ]
  include_dirs = [ "include" ]
  cflags = []
  if (target_cpu == "arm") {
    cflags += [ "-DBINDER_IPC_32BIT" ]
  }
}

quickfixms_sources = [
  "src/quick_fix_manager_apply_task.cpp",
  "src/quick_fix_manager_service.cpp",
  "src/quick_fix_manager_service_ability.cpp",
]

ohos_shared_library("quickfixms") {
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    cfi_policy = "adaptive"
    debug = false
  }
  branch_protector_ret = "pac_ret"
  include_dirs = [ "${ability_runtime_path}/interfaces/kits/native/appkit/ability_bundle_manager_helper" ]
  shlib_type = "sa"
  configs = [
    "${ability_runtime_services_path}/common:common_config",
    "${ability_runtime_services_path}/common:optimize_config",
  ]
  public_configs = [ ":quickfixms_config" ]

  sources = quickfixms_sources

  defines = [ "AMS_LOG_TAG = \"QuickFixService\"" ]

  deps = [
    "${ability_runtime_innerkits_path}/app_manager:app_manager",
    "${ability_runtime_innerkits_path}/quick_fix:quickfix_manager",
    "${ability_runtime_native_path}/appkit:appkit_manager_helper",
    "${ability_runtime_services_path}/common:perm_verification",
  ]

  external_deps = [
    "ability_base:want",
    "bundle_framework:appexecfwk_base",
    "bundle_framework:appexecfwk_core",
    "c_utils:utils",
    "common_event_service:cesfwk_innerkits",
    "eventhandler:libeventhandler",
    "hilog:libhilog",
    "hitrace:hitrace_meter",
    "init:libbegetutil",
    "ipc:ipc_single",
    "safwk:system_ability_fwk",
    "samgr:samgr_proxy",
  ]

  if (ability_runtime_child_process) {
    defines += [ "SUPPORT_CHILD_PROCESS" ]
  }

  subsystem_name = "ability"
  part_name = "ability_runtime"
}

# Note: Just for test
ohos_static_library("quickfixms_static") {
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    debug = false
  }
  branch_protector_ret = "pac_ret"
  include_dirs = [ "${ability_runtime_path}/interfaces/kits/native/appkit/ability_bundle_manager_helper" ]
  configs = [ "${ability_runtime_services_path}/common:common_config" ]
  public_configs = [ ":quickfixms_config" ]

  sources = quickfixms_sources

  defines = [ "AMS_LOG_TAG = \"QuickFixService\"" ]

  deps = [
    "${ability_runtime_innerkits_path}/app_manager:app_manager",
    "${ability_runtime_innerkits_path}/quick_fix:quickfix_manager",
    "${ability_runtime_services_path}/common:perm_verification",
  ]

  external_deps = [
    "ability_base:want",
    "bundle_framework:appexecfwk_base",
    "bundle_framework:appexecfwk_core",
    "c_utils:utils",
    "common_event_service:cesfwk_innerkits",
    "eventhandler:libeventhandler",
    "hilog:libhilog",
    "hitrace:hitrace_meter",
    "init:libbegetutil",
    "ipc:ipc_single",
    "safwk:system_ability_fwk",
    "samgr:samgr_proxy",
  ]

  subsystem_name = "ability"
  part_name = "ability_runtime"
}