# Copyright (C) 2025-2026 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("../../accessibility_manager_service.gni")

services_ext_path = "./"

config("aams_ext_config") {
  visibility = [ ":*" ]

  include_dirs = [
    "include",
    "../../common/log/include",
    "../aams/include",
  ]

  defines = [
    "AAMS_LOG_TAG = \"accessibility\"",
    "AAMS_LOG_DOMAIN = 0xD001D00",
  ]

  if (build_variant == "user") {
    defines += [ "RELEASE_VERSION" ]
  }

  defines += accessibility_default_defines
}

aams_ext_files = [
  "${services_ext_path}/src/accessibility_circle_drawing_manager.cpp",
  "${services_ext_path}/src/ext_utils.cpp",
  "${services_ext_path}/src/accessibility_notification_helper.cpp",
  "${services_ext_path}/src/export_api.cpp",
  "${services_ext_path}/src/accessibility_input_interceptor.cpp",
  "${services_ext_path}/src/accessibility_event_transmission.cpp",
  "${services_ext_path}/src/accessibility_keyevent_filter.cpp",
  "${services_ext_path}/src/accessibility_mouse_autoclick.cpp",
  "${services_ext_path}/src/accessibility_mouse_key.cpp",
  "${services_ext_path}/src/accessibility_screen_touch.cpp",
  "${services_ext_path}/src/accessibility_touchEvent_injector.cpp",
  "${services_ext_path}/src/accessibility_zoom_gesture.cpp",
  "${services_ext_path}/src/full_screen_magnification_manager.cpp",
  "${services_ext_path}/src/magnification_manager.cpp",
  "${services_ext_path}/src/magnification_menu_manager.cpp",
  "${services_ext_path}/src/magnification_menu.cpp",
  "${services_ext_path}/src/magnification_window.cpp",
  "${services_ext_path}/src/touch_exploration_multi_finger_gesture.cpp",
  "${services_ext_path}/src/touch_exploration_single_finger_gesture.cpp",
  "${services_ext_path}/src/window_magnification_gesture.cpp",
  "${services_ext_path}/src/window_magnification_manager.cpp",
  "${services_ext_path}/src/extend_service_manager.cpp",
  "${services_ext_path}/src/accessible_ability_manager_service_event_handler.cpp",
  "${services_ext_path}/src/accessibility_extend_power_manager.cpp",
]

ohos_shared_library("aams_ext") {
  branch_protector_ret = "pac_ret"
  sanitize = {
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
  }

  sources = aams_ext_files

  if (accessibility_feature_display_manager) {
    sources += [ "${services_ext_path}/src/accessibility_display_manager.cpp" ]
  }

  configs = [
    ":aams_ext_config",
    "../../resources/config/build:coverage_flags",
  ]

  deps = [
    "../../common/interface:accessibility_interface",
    "../../interfaces/innerkits/common:accessibility_common"
  ]

  external_deps = [
    "ability_base:zuri",
    "ability_runtime:wantagent_innerkits",
    "bundle_framework:appexecfwk_core",
    "c_utils:utils",
    "ffrt:libffrt",
    "graphic_2d:2d_graphics",
    "graphic_2d:librender_service_client",
    "graphic_2d:librender_service_base",
    "hisysevent:libhisysevent",
    "i18n:intl_util",
    "init:libbegetutil",
    "input:libmmi-client",
    "os_account:os_account_innerkits",
    "power_manager:powermgr_client",
    "resource_management:global_resmgr",
    "samgr:samgr_proxy",
    "safwk:system_ability_fwk",
    "time_service:time_client",
    "window_manager:libdm",
    "window_manager:libwm",
    "eventhandler:libeventhandler",
  ]

  if (defined(global_parts_info) &&
    defined(
      global_parts_info.notification_distributed_notification_service)) {
    external_deps += [ "distributed_notification_service:ans_innerkits" ]
  }

  if (accessibility_feature_display_manager) {
    external_deps += [ "display_manager:displaymgr" ]
  }
 
  if (accessibility_watch_feature) {
    external_deps += [ "resource_schedule_service:ressched_client" ]
  }

  install_enable = true

  subsystem_name = "barrierfree"
  part_name = "accessibility"
}