# Copyright (c) 2021-2025 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

if ((defined(ark_standalone_build) && ark_standalone_build) ||
    (defined(ark_static_standalone_build) && ark_static_standalone_build)) {
  import("//arkcompiler/runtime_core/static_core/ark_config.gni")
} else {
  import(
      "//build/config/components/runtime_core/static_core/ark_common_config.gni")
}

if (ark_standalone_build) {
  import("$build_root/ark.gni")
} else {
  import("//build/ohos.gni")
}

ohos_executable("ets2panda") {
  sources = [ "main.cpp" ]

  include_dirs = [
    "$target_gen_dir",
    "$target_gen_dir/include",
  ]
  if ((defined(ark_standalone_build) && ark_standalone_build) ||
      (defined(ark_static_standalone_build) && ark_static_standalone_build)) {
    configs = [ "$ark_root:ark_config" ]
  } else {
    configs = [
      "//build/config/components/runtime_core/static_core:ark_common_config",
    ]
  }

  if (ark_standalone_build || ark_static_standalone_build) {
    configs += [
      "$ark_root/assembler:arkassembler_public_config",
      "$ark_root/libarkfile:arkfile_public_config",
      "$ark_root/libarkbase:arkbase_public_config",
      "$ark_root/bytecode_optimizer:bytecodeopt_public_config",
      "$ark_root/runtime:arkruntime_public_config",
      "$ark_root/compiler:arkcompiler_public_config",
    ]
  }

  configs += [
    "$ark_es2panda_root:libes2panda_public_config",
    "$ark_es2panda_root:libes2panda_config",
  ]

  deps = [
    "$ark_es2panda_root:libes2panda_frontend_static",
    "$ark_es2panda_root:libes2panda_public_frontend_static",
  ]

  if (ark_standalone_build) {
    deps += [
      "$ark_root/bytecode_optimizer:libarktsbytecodeopt_package",
      "$ark_root/libarkbase:libarktsbase_package",
      "$ark_root/libarkfile:libarktsfile_package",
    ]
  }

  external_deps = [
    "runtime_core:libarktsassembler_package",
    "runtime_core:libarktsbase_package",
    "runtime_core:libarktsbytecodeopt_package",
    "runtime_core:libarktscompiler_package",
    "runtime_core:libarktsfile_package",
    sdk_libc_secshared_dep,
  ]

  if (!(ark_standalone_build || ark_static_standalone_build)) {
    external_deps += [
      "runtime_core:assembler_headers",
      "runtime_core:bytecode_optimizer_headers",
      "runtime_core:compiler_headers",
      "runtime_core:libpandabase_headers",
      "runtime_core:libpandafile_headers",
      "runtime_core:runtime_gen_headers",
      "runtime_core:runtime_headers",
      "runtime_core:verification_headers",
    ]
  }

  libs = platform_libs
  ldflags = platform_ldflags
  if (is_linux) {
    libs += [ "stdc++fs" ]
  }

  output_name = "es2panda"
  install_enable = true
  part_name = "ets_frontend"
  subsystem_name = "arkcompiler"
}