# Copyright (c) 2021-2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/arkui/ace_engine/ace_config.gni")

config("uisession_manager_public_config") {
  visibility = [ ":*" ]
  include_dirs = [
    "$ace_root/frameworks",
    "include/",
    "$ace_root/interfaces/inner_api/ui_session",
    "$ace_root/interfaces/inner_api/ace_kit/include",
  ]
  if (current_os == "ohos") {
    defines = [ "OHOS_PLATFORM" ]
  }
  cflags = []
  if (target_cpu == "arm") {
    cflags += [ "-DBINDER_IPC_32BIT" ]
  }
}

ohos_shared_library("ui_session") {
  if (current_os == "ohos") {
    sanitize = {
      integer_overflow = true
      boundary_sanitize = true
      debug = ace_sanitize_debug
    }
  }
  sources = [
    "$ace_root/adapter/ohos/entrance/ui_session/ui_content_proxy.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_content_stub.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_content_stub_impl.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_report_proxy.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_report_stub.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_session_ipc_util.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_session_json_util.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_session_manager_ohos.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_translate_request_util.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/large_string_ashmem.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/content_change_config_impl.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/get_inspector_tree_config_impl.cpp",
    "$ace_root/adapter/ohos/entrance/ui_session/ui_session_trace.cpp",
  ]

  configs = [ "$ace_root:ace_config" ]

  public_configs = [ ":uisession_manager_public_config" ]

  external_deps = [
    "ability_base:want",
    "access_token:libaccesstoken_sdk",
    "access_token:libtokenid_sdk",
    "bounds_checking_function:libsec_shared",
    "cJSON:cjson",
    "c_utils:utils",
    "graphic_2d:2d_graphics",
    "graphic_2d:librender_service_client",
    "eventhandler:libeventhandler",
    "hilog:libhilog",
    "hitrace:hitrace_meter",
    "image_framework:image_native",
    "ipc:ipc_core",
    "samgr:samgr_proxy",
  ]

  subsystem_name = ace_engine_subsystem
  innerapi_tags = [ "platformsdk_indirect" ]
  part_name = ace_engine_part
}

group("ui_session_example") {
  deps = [ "ui_session_sample:ui_sa" ]
}