# Copyright (c) 2024 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/arkui/ace_engine/ace_config.gni")

ohos_shared_library("componenttest") {
  if (defined(current_platform.name)) {
    platform = current_platform.name

    defines = []
    cflags_cc = []
    config = {
    }
    if (defined(current_platform.config)) {
      config = current_platform.config
    }
    if (defined(config.defines)) {
      defines += config.defines
    }
    if (defined(config.cflags_cc)) {
      cflags_cc += config.cflags_cc
    }
    configs = [ "$ace_root:ace_config" ]

    sources = [
      "js_component_test.cpp",
      "js_component_test_component.cpp",
      "js_component_test_matcher.cpp",
      "js_component_test_tester.cpp",
      "js_component_test_utils.cpp",
    ]

    deps = [
      "$ace_root/build:libace_compatible",
      "../utils:napi_utils_static_${platform}",
    ]

    if (defined(config.libace_target)) {
      deps += [ config.libace_target ]
    }

    external_deps = [ "napi:ace_napi" ]

    include_dirs = [
      "$ace_root",
      "$ace_root/frameworks",
      "$root_out_dir/arkui/framework",
    ]

    relative_install_dir = "module/arkui"
    subsystem_name = ace_engine_subsystem
    part_name = ace_engine_part
  }
}