# Copyright (c) 2024-2025 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/arkui/ace_engine/ace_config.gni")

config("ace_kit_config") {
  include_dirs = [ "$ace_root/interfaces/inner_api/ace_kit/include" ]
}

ohos_source_set("ace_kit") {
  subsystem_name = ace_engine_subsystem
  part_name = ace_engine_part

  public_configs = [ ":ace_kit_config" ]

  configs = [ "$ace_root:ace_config" ]

  defines = [
    "USE_ARK_ENGINE",
    "NOGDI",
  ]

  cflags_cc = [ "-Wno-macro-redefined" ]

  sources = [
    "src/agingadapation/aging_adapation_dialog_util.cpp",
    "src/animation/animation_utils.cpp",
    "src/napi/napi_parser.cpp",
    "src/ani/ani_parser.cpp",
    "src/properties/property.cpp",
    "src/resource/resource_parser.cpp",
    "src/utils/measure_utils.cpp",
    "src/view/components/column.cpp",
    "src/view/components/stack.cpp",
    "src/view/components/custom_node.cpp",
    "src/view/components/menu_view.cpp",
    "src/view/components/tabs.cpp",
    "src/view/components/text.cpp",
    "src/view/components/symbol.cpp",
    "src/view/components/badge.cpp",
    "src/view/draw/content_modifier.cpp",
    "src/view/draw/modifier_adapter.cpp",
    "src/view/extend_pattern.cpp",
    "src/view/frame_node_impl.cpp",
    "src/view/layout/box_layout_algorithm.cpp",
    "src/view/overlay/overlay_manager_impl.cpp",
    "src/view/scroller_impl.cpp",
    "src/view/theme/theme_factory.cpp",
    "src/view/theme/theme_style_impl.cpp",
    "src/view/theme/token_colors.cpp",
    "src/view/theme/token_theme.cpp",
    "src/view/ui_context_impl.cpp",
    "src/view/view.cpp",
    "src/view_factory/abstract_view_factory.cpp",
    "src/view_stack/view_stack_processor.cpp",
  ]

  include_dirs = [
    "$ace_root",
    "$ace_root/frameworks",
    "$ace_root/interfaces/inner_api/ace_kit/src",
    "$ace_root/frameworks/core/interfaces/native/generated/interface",
  ]

  deps = [
    "$ace_root/frameworks/bridge/arkts_frontend/arkoala_generator:idlize_gen",
  ]
  external_deps = [ "hilog:libhilog" ]

  if (is_arkui_x) {
    include_dirs += [
      "//foundation/arkui/napi",
      "//third_party/node/src",
    ]
    deps += [
      "${ace_graphic}/rosen/modules/render_service_client:librender_service_client_static",
      "//third_party/libuv:uv_static",
    ]
  } else {
    external_deps += [
      "graphic_2d:librender_service_client",
      "napi:ace_napi",
      "node:node_header_notice",
      "libuv:uv",
      "ets_runtime:libark_jsruntime",
    ]
    if (current_os == "ohos") {
      external_deps += [ "eventhandler:libeventhandler" ]
    }
  }

  if (current_os == "ohos") {
    external_deps += [ "ipc:ipc_single" ]
  }
}