# Copyright (C) 2023-2025 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("../../app_domain_verify.gni")

config("app_domain_verify_agent_verifier_config") {
  visibility = [ ":*" ]
  include_dirs = [
    "include",
    "include/constant",
    "${app_domain_verify_common_path}/include",
    "${app_domain_verify_frameworks_common_path}/include",
    "${app_domain_verify_frameworks_common_path}/include/httpsession",
    "${app_domain_verify_frameworks_common_path}/include/utils",
    "${app_domain_verify_frameworks_common_path}/include/bms",
  ]
  configs = [ "//build/config/compiler:exceptions" ]
  ldflags = [ "-Wl,--exclude-libs=ALL" ]
  cflags = [
    "-fdata-sections",
    "-ffunction-sections",
    "-fstack-protector-strong",
    "-D_FORTIFY_SOURCE=2",
    "-Os",
  ]

  cflags_cc = [
    "-fstack-protector-strong",
    "-Os",
  ]
}

ohos_shared_library("app_domain_verify_agent_verifier") {
  branch_protector_ret = "pac_ret"
  sources = [
    "src/domain_json_util.cpp",
    "src/domain_verifier.cpp",
    "src/verify_http_task.cpp",
    "src/verify_task.cpp",
  ]
  public_configs = [ ":app_domain_verify_agent_verifier_config" ]
  deps = [
    "${app_domain_verify_client_path}:app_domain_verify_mgr_client",
    "${app_domain_verify_common_path}:app_domain_verify_common",
    "${app_domain_verify_frameworks_common_path}:app_domain_verify_frameworks_common",
  ]
  version_script = "verifier.versionscript"

  external_deps = [
    "ability_base:base",
    "ability_base:want",
    "ability_runtime:ability_manager",
    "bundle_framework:appexecfwk_base",
    "bundle_framework:appexecfwk_core",
    "cJSON:cjson",
    "c_utils:utils",
    "curl:curl_shared",
    "eventhandler:libeventhandler",
    "ffrt:libffrt",
    "hilog:libhilog",
    "hisysevent:libhisysevent",
    "ipc:ipc_core",
    "netstack:http_client",
    "os_account:os_account_innerkits",
    "safwk:system_ability_fwk",
    "samgr:samgr_proxy",
  ]
  defines = []
  if (build_variant == "user") {
    defines += [ "IS_RELEASE_VERSION" ]
  }
  sanitize = {
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
    integer_overflow = true
    ubsan = true
  }
  subsystem_name = "bundlemanager"
  part_name = "app_domain_verify"
}