# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("../../../../appexecfwk.gni")

ohos_shared_library("innerbundlemanager") {
  branch_protector_ret = "pac_ret"

  sanitize = {
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
    integer_overflow = true
    ubsan = true
  }

  include_dirs = [ "${kits_path}/js/common" ]

  defines = [
    "APP_LOG_TAG = \"BMS\"",
    "LOG_DOMAIN = 0xD001120",
  ]

  cflags = [
    "-Os",
    "-fstack-protector-strong",
  ]

  cflags_cc = [
    "-Os",
    "-fstack-protector-strong",
  ]

  sources = []

  deps = [
    "${base_path}:appexecfwk_base",
    "${common_path}:libappexecfwk_common",
    "${core_path}:appexecfwk_core",
    "${kits_path}/js/common:bundle_napi_common",
  ]

  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
    "libuv:uv",
    "napi:ace_napi",
    "node:node_header_notice",
    "samgr:samgr_proxy",
  ]
  if (bundle_framework_launcher) {
    defines += [ "BUNDLE_FRAMEWORK_LAUNCHER" ]
    sources += [
      "bundle_status_callback.cpp",
      "js_launcher.cpp",
      "js_launcher_mgr.cpp",
    ]
    external_deps += [
      "ability_base:want",
      "common_event_service:cesfwk_core",
      "common_event_service:cesfwk_innerkits",
      "ipc:ipc_core",
    ]
  } else {
    sources += [ "js_launcher_unsupported.cpp" ]
  }

  relative_install_dir = "module/bundle"
  subsystem_name = "bundlemanager"
  part_name = "bundle_framework"
}