# Copyright (C) 2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/multimedia/av_codec/config.gni")

ohos_shared_headers("capi_packages") {
  include_dirs = [ "$av_codec_root_dir/interfaces/kits/c" ]
  deps = []
  if (av_codec_support_capi) {
    deps += [
      "$av_codec_root_dir/interfaces/kits/c:native_media_acodec",
      "$av_codec_root_dir/interfaces/kits/c:native_media_adec",
      "$av_codec_root_dir/interfaces/kits/c:native_media_aenc",
      "$av_codec_root_dir/interfaces/kits/c:native_media_avcencinfo",
      "$av_codec_root_dir/interfaces/kits/c:native_media_avdemuxer",
      "$av_codec_root_dir/interfaces/kits/c:native_media_avmuxer",
      "$av_codec_root_dir/interfaces/kits/c:native_media_avsource",
      "$av_codec_root_dir/interfaces/kits/c:native_media_codecbase",
      "$av_codec_root_dir/interfaces/kits/c:native_media_vdec",
      "$av_codec_root_dir/interfaces/kits/c:native_media_venc",
    ]
  }
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

config("av_codec_capi_header_config") {
  include_dirs = [
    "$av_codec_root_dir/frameworks/native/capi/common",
    "$av_codec_root_dir/interfaces/inner_api/native",
    "$av_codec_root_dir/interfaces/kits/c",
    "$av_codec_root_dir/services/dfx/include",
    "$av_codec_root_dir/services/utils/include",
  ]
  defines = []
  if (av_codec_support_drm) {
    defines += [ "SUPPORT_DRM" ]
  }
  cflags_cc = [ "-fno-rtti" ]
}

config("av_codec_capi_compile_config") {
  cflags = [
    "-std=c++17",
    "-fstack-protector-all",
    "-FPIC",
    "-FS",
    "-O2",
    "-D_FORTIFY_SOURCE=2",
    "-fno-common",
    "-fno-exceptions",
    "-Wall",
    "-Wdate-time",
    "-Wformat=2",
    "-Wshadow",
  ]
}

config("av_cenc_info_capi_config") {
  include_dirs = [
    "$av_codec_root_dir/frameworks/native/capi/common",
    "$av_codec_root_dir/interfaces/inner_api/native",
    "$av_codec_root_dir/interfaces/kits/c",
    "$av_codec_root_dir/services/dfx/include",
    "$av_codec_root_dir/services/utils/include",
  ]
  defines = []
}

ohos_shared_library("avcodec_api_metrics") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sanitize = av_codec_sanitize
  sources = [
    "$av_codec_root_dir/frameworks/native/capi/common/api_metrics_util.cpp",
  ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
  ]

  defines = []
  if (av_codec_enable_api_metrics) {
    external_deps += [ "api_metrics:histogrammanager" ]
    defines += [ "HISTOGRAMMANAGER_ENABLE" ]
  }
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("avcodec_hiappevent") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sanitize = av_codec_sanitize
  sources =
      [ "$av_codec_root_dir/frameworks/native/capi/common/hiappevent_util.cpp" ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  external_deps = [
    "c_utils:utils",
    "hiappevent:hiappevent_innerapi",
    "hilog:libhilog",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_avmuxer") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources =
      [ "$av_codec_root_dir/frameworks/native/capi/avmuxer/native_avmuxer.cpp" ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_api_metrics",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
    "$av_codec_root_dir/interfaces/kits/c:native_media_codecbase",
  ]

  external_deps = [
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_avdemuxer") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources = [
    "$av_codec_root_dir/frameworks/native/capi/avdemuxer/native_avdemuxer.cpp",
  ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_api_metrics",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
  ]

  external_deps = [
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]

  if (av_codec_support_drm) {
    external_deps += [
      "drm_framework:drm_framework",
      "drm_framework:native_drm",
    ]
  }

  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_avsource") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources = [
    "$av_codec_root_dir/frameworks/native/capi/avsource/native_avsource.cpp",
  ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_api_metrics",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
  ]

  external_deps = [
    "bundle_framework:appexecfwk_base",
    "bundle_framework:appexecfwk_core",
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
    "netmanager_base:net_security_config_if",
    "samgr:samgr_proxy",
  ]
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_codecbase") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources = [
    "$av_codec_root_dir/frameworks/native/capi/avcodec/native_avcodec_base.cpp",
    "$av_codec_root_dir/frameworks/native/capi/avcodec/native_avcodec_videobase.cpp",
  ]
  if (av_codec_support_codeclist) {
    sources += [ "$av_codec_root_dir/frameworks/native/capi/common/native_avcapability.cpp" ]
  }

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
  ]
  external_deps = [
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_acodec") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources = [
    "$av_codec_root_dir/frameworks/native/capi/avcodec/native_audio_codec.cpp",
  ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_api_metrics",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
    "$av_codec_root_dir/interfaces/kits/c:native_media_codecbase",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
  ]

  external_deps = [
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  if (av_codec_support_drm) {
    external_deps += [
      "drm_framework:drm_framework",
      "drm_framework:native_drm",
      "hisysevent:libhisysevent",
    ]
  }
  innerapi_tags = [ "ndk" ]
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_adec") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources = [ "$av_codec_root_dir/frameworks/native/capi/avcodec/native_audio_decoder.cpp" ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_api_metrics",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
    "$av_codec_root_dir/interfaces/kits/c:native_media_codecbase",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
  ]

  external_deps = [
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_aenc") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources = [ "$av_codec_root_dir/frameworks/native/capi/avcodec/native_audio_encoder.cpp" ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_api_metrics",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
    "$av_codec_root_dir/interfaces/kits/c:native_media_codecbase",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
  ]

  external_deps = [
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_vdec") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources = [ "$av_codec_root_dir/frameworks/native/capi/avcodec/native_video_decoder.cpp" ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_api_metrics",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
    "$av_codec_root_dir/interfaces/kits/c:native_media_codecbase",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
  ]

  external_deps = [
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  if (av_codec_support_drm) {
    external_deps += [
      "drm_framework:drm_framework",
      "drm_framework:native_drm",
      "hisysevent:libhisysevent",
    ]
  }
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_venc") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sanitize = av_codec_sanitize
  sources = [
    "$av_codec_root_dir/frameworks/native/capi/avcodec/native_video_encoder.cpp",
    "$av_codec_root_dir/frameworks/native/capi/avcodec/preprocessor.cpp",
    "$av_codec_root_dir/frameworks/native/capi/avcodec/preprocessor_encoder.cpp",
    "$av_codec_root_dir/frameworks/native/capi/avcodec/preprocessor_format_utils.cpp",
    "$av_codec_root_dir/frameworks/native/capi/avcodec/preprocessor_manager.cpp",
    "$av_codec_root_dir/frameworks/native/capi/avcodec/shared_surface_manager.cpp",
    "$av_codec_root_dir/frameworks/native/capi/avcodec/video_encoder_object.cpp",
  ]

  public_configs = [ ":av_codec_capi_header_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  include_dirs = [
    "$av_codec_root_dir/frameworks/native/avcodec/pre_processing/cpu_image_processor",
    "$av_codec_root_dir/frameworks/native/avcodec/pre_processing/fast_kits_interface",
    "$av_codec_root_dir/frameworks/native/avcodec/pre_processing/frame_drop",
  ]

  defines = []
  if (build_variant != "user") {
    defines += [ "BUILD_ENG_VERSION" ]
  }
  if (defined(global_parts_info) &&
      defined(global_parts_info.UtilityApplication_FAST)) {
    print("native_media_venc: FAST_KIT_ENABLED=true")
    defines += [ "FAST_KIT_ENABLED=true" ]
  } else {
    print("native_media_venc: FAST_KIT_ENABLED=false")
    defines += [ "FAST_KIT_ENABLED=false" ]
  }

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_api_metrics",
    "$av_codec_root_dir/interfaces/kits/c:avcodec_hiappevent",
    "$av_codec_root_dir/interfaces/kits/c:native_media_codecbase",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
    "$av_codec_root_dir/services/services/sa_avcodec/client:statistics_event_ipc",
  ]

  external_deps = [
    "c_utils:utils",
    "drivers_interface_display:libdisplay_commontype_proxy_2.2",
    "graphic_surface:surface",
    "graphic_surface:sync_fence",
    "hilog:libhilog",
    "hitrace:hitrace_meter",
    "init:libbegetutil",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  output_extension = "so"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("native_media_avcencinfo") {
  branch_protector_ret = "pac_ret"
  install_enable = true
  sources = [
    "$av_codec_root_dir/frameworks/native/capi/avcencinfo/native_cencinfo.cpp",
  ]

  sanitize = av_codec_sanitize

  public_configs = [ ":av_cenc_info_capi_config" ]
  configs = [ ":av_codec_capi_compile_config" ]

  deps = [
    "$av_codec_root_dir/interfaces/inner_api/native:av_codec_client",
    "$av_codec_root_dir/interfaces/kits/c:native_media_codecbase",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
  ]

  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "media_foundation:native_media_core",
  ]
  output_extension = "so"
  innerapi_tags = [ "ndk" ]
  subsystem_name = "multimedia"
  part_name = "av_codec"
}