# Copyright (C) 2023-2025 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/multimedia/av_codec/config.gni")

config("av_codec_media_engine_modules_pts_and_index_convert_config") {
  include_dirs = [
    "$av_codec_root_dir/services/media_engine/modules",
    "$av_codec_root_dir/services/media_engine/modules/demuxer",
    "$av_codec_root_dir/services/media_engine/modules/pts_index_conversion",
  ]
}

config("av_codec_media_engine_modules_config") {
  defines = [
    "HST_ANY_WITH_NO_RTTI",
    "MEDIA_OHOS",
  ]

  if (defined(av_codec_support_video_processing_engine) &&
      av_codec_support_video_processing_engine) {
    defines += [ "USE_VIDEO_PROCESSING_ENGINE" ]
  }

  if (av_codec_enable_start_stop_on_demand) {
    defines += [ "SUPPORT_START_STOP_ON_DEMAND" ]
  }

  cflags = [
    "-fno-exceptions",
    "-Wall",
    "-fno-common",
    "-fstack-protector-all",
    "-Wshadow",
    "-FPIC",
    "-FS",
    "-O2",
    "-D_FORTIFY_SOURCE=2",
    "-Wformat=2",
    "-Wdate-time",
  ]

  cflags_cc = [
    "-std=c++17",
    "-fno-rtti",
  ]

  include_dirs = [
    "$av_codec_root_dir/interfaces",
    "$av_codec_root_dir/interfaces/inner_api/native",
    "$av_codec_root_dir/services/drm_decryptor",
    "$av_codec_root_dir/services/media_engine/modules",
    "$av_codec_root_dir/services/utils/include",
    "$av_codec_root_dir/services/engine/codeclist",
    "$av_codec_root_dir/services/engine/codec/include/video",
    "$av_codec_root_dir/services/engine/base/include",
    "$av_codec_root_dir/services/services/sa_avcodec/client",
    "$av_codec_root_dir/services/services/common/event_manager",
    "$av_codec_root_dir/services/media_engine/modules/demuxer",
    "$av_codec_root_dir/services/media_engine/modules/interstitial",
    "$av_codec_root_dir/services/utils/include",
  ]
}

ohos_shared_library("av_codec_media_engine_modules") {
  branch_protector_ret = "pac_ret"
  install_enable = true

  sanitize = av_codec_sanitize

  configs = [
    ":av_codec_media_engine_modules_config",
    "$av_codec_root_dir/services/dfx:av_codec_service_log_dfx_public_config",
  ]

  sources = [
    "$av_codec_root_dir/services/drm_decryptor/codec_drm_decrypt.cpp",
    "demuxer/base_stream_demuxer.cpp",
    "demuxer/demuxer_plugin_manager.cpp",
    "demuxer/media_demuxer.cpp",
    "demuxer/sample_queue.cpp",
    "demuxer/sample_queue_controller.cpp",
    "demuxer/stream_demuxer.cpp",
    "demuxer/type_finder.cpp",
    "interstitial/interstitial_controller.cpp",
    "interstitial/interstitial_scheduler.cpp",
    "interstitial/interstitial_vod_strategies.cpp",
    "interstitial/interstitial_live_strategies.cpp",
    "media_codec/media_codec.cpp",
    "muxer/data_sink_fd.cpp",
    "muxer/data_sink_file.cpp",
    "muxer/media_muxer.cpp",
    "post_processor/side_output_surface_processor.cpp",
    "post_processor/video_post_processor_factory.cpp",
    "pts_index_conversion/pts_and_index_conversion.cpp",
    "sink/audio_sampleformat.cpp",
    "sink/audio_sink.cpp",
    "sink/calc_max_amplitude.cpp",
    "sink/media_sync_manager.cpp",
    "sink/media_synchronous_sink.cpp",
    "sink/subtitle_sink.cpp",
    "sink/video_sink.cpp",
    "source/audio_capture/audio_capture_module.cpp",
    "source/audio_capture/audio_type_translate.cpp",
    "source/source.cpp",
  ]

  if (defined(av_codec_support_video_processing_engine) &&
      av_codec_support_video_processing_engine) {
    sources += [ "post_processor/super_resolution_post_processor.cpp" ]
  }

  deps = [
    "$av_codec_root_dir/services/engine/base:av_codec_codec_base",
    "$av_codec_root_dir/services/services/sa_avcodec/client:statistics_event_ipc",
  ]

  public_configs =
      [ ":av_codec_media_engine_modules_pts_and_index_convert_config" ]

  external_deps = [
    "access_token:libaccesstoken_sdk",
    "access_token:libtokenid_sdk",
    "audio_framework:audio_capturer",
    "bundle_framework:appexecfwk_base",
    "bundle_framework:appexecfwk_core",
    "c_utils:utils",
    "ffmpeg:libohosffmpeg",
    "graphic_surface:surface",
    "graphic_surface:sync_fence",
    "hilog:libhilog",
    "hisysevent:libhisysevent",
    "hitrace:libhitracechain",
    "hitrace:hitrace_meter",
    "init:libbegetutil",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "openssl:libcrypto_shared",
    "safwk:system_ability_fwk",
    "samgr:samgr_proxy",
  ]

  if (defined(av_codec_support_video_processing_engine) &&
      av_codec_support_video_processing_engine) {
    external_deps += [ "video_processing_engine:videoprocessingengine" ]
  }

  if (av_codec_support_drm) {
    defines = [ "SUPPORT_DRM" ]
  }
  if (av_codec_support_drm) {
    external_deps += [ "drm_framework:drm_framework" ]
  }

  subsystem_name = "multimedia"
  part_name = "av_codec"
}