# Copyright (c) 2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/test.gni")
import("//foundation/multimedia/av_codec/config.gni")

module_output_path = "av_codec/AVCodec_Video/unittest"
event_handler_dir =
    "$av_codec_root_dir/services/services/common/event_manager/event_handler"

av_codec_unittest_cflags = [
  "-std=c++17",
  "-fno-rtti",
  "-Wall",
  "-fno-common",
  "-fstack-protector-strong",
  "-Wshadow",
  "-FPIC",
  "-FS",
  "-O2",
  "-D_FORTIFY_SOURCE=2",
  "-fvisibility=hidden",
  "-Wformat=2",
  "-Wdate-time",
  "-Werror",
  "-Wextra",
  "-Wimplicit-fallthrough",
  "-Wsign-compare",
  "-Wno-unused-function",
  "-Wno-unused-parameter",
  "-Dprivate=public",
  "-Dprotected=public",
]

group("codec_server_test") {
  testonly = true
  deps = [ ":video_codec_server_coverage_unit_test" ]
}

##################################################################################################################
codec_server_coverage_include_dirs = [
  "./",
  "../vcodec_framework_test/common/utils",
  "./mock/include",
  "$av_codec_root_dir/interfaces/kits/c",
  "$av_codec_root_dir/interfaces/inner_api/native",
  "$av_codec_root_dir/services/dfx/include",
  "$av_codec_root_dir/services/drm_decryptor",
  "$av_codec_root_dir/services/engine/base/include/",
  "$av_codec_root_dir/services/engine/codec/include/audio/",
  "$av_codec_root_dir/services/engine/common/include/",
  "$av_codec_root_dir/services/include",
  "$av_codec_root_dir/services/services/codec/server/video",
  "$av_codec_root_dir/services/services/codec/server/video/features/smart_fluency_decoding",
  "$av_codec_root_dir/services/services/codec/server/video/features/smart_fluency_decoding/interfaces",
  "$av_codec_root_dir/services/services/common",
  "$av_codec_root_dir/services/services/common/event_manager/",
  "$av_codec_root_dir/services/services/codec/server/video/post_processing",
  "$av_codec_root_dir/services/utils/include",
  "$av_codec_root_dir/services/services/codeclist/server/",

  # av_codec_engine_codeclist_mock
  "$av_codec_root_dir/services/engine/codeclist",
  "$av_codec_root_dir/services/media_engine/plugins/ffmpeg_adapter/common/",
  "$av_codec_root_dir/services/services/common/adaptive_framerate_controller",
  "$av_codec_root_dir/services/services/codeclist/ipc",
  "$av_codec_root_dir/services/services/codec/ipc",
  "$av_codec_root_dir/services/services/sa_avcodec/ipc",
  "$av_codec_root_dir/services/services/sa_avcodec/server/include",
  "$av_codec_root_dir/services/services/common/event_manager",
  "$av_codec_root_dir/services/services/common/event_manager/event_handler/background_event_handler",
  "$av_codec_root_dir/services/services/common/event_manager/event_handler/instance_memory_update_event_handler",
  "$av_codec_root_dir/services/services/common/event_manager/event_handler/instance_operation_event_handler",
  "$av_codec_root_dir/services/services/common/event_manager/event_handler/statistics_event_handler",

  "$av_codec_root_dir/test/unittest/common",
  "$av_codec_root_dir/test/unittest/common/common_mock/avformat",
  "$av_codec_root_dir/test/unittest/common/common_mock/avformat/capi",
  "$av_codec_root_dir/test/unittest/video_test/codeclist_test",
  "$av_codec_root_dir/test/unittest/video_test/codeclist_test/capi",
]

ohos_unittest("video_codec_server_coverage_unit_test") {
  sanitize = av_codec_test_sanitize
  module_out_path = module_output_path
  cflags = av_codec_unittest_cflags
  cflags_cc = cflags
  include_dirs = codec_server_coverage_include_dirs
  defines = av_codec_defines
  if (av_codec_enable_special_codec) {
    defines += [ "AV_CODEC_AUDIO_SPECIAL_CAPACITY" ]
  }

  sources = [
    "$av_codec_root_dir/frameworks/native/common/avcodec_errors.cpp",
    "$av_codec_root_dir/services/dfx/avcodec_dfx_component.cpp",
    "$av_codec_root_dir/services/services/codec/ipc/codec_listener_proxy.cpp",
    "$av_codec_root_dir/services/services/codec/ipc/codec_service_stub.cpp",
    "$av_codec_root_dir/services/services/codec/server/video/codec_factory.cpp",
    "$av_codec_root_dir/services/services/codec/server/video/codec_param_checker.cpp",
    "$av_codec_root_dir/services/services/codec/server/video/codec_server.cpp",
    "$av_codec_root_dir/services/services/codec/server/video/post_processing/dynamic_controller.cpp",
    "$av_codec_root_dir/services/services/codec/server/video/post_processing/dynamic_interface.cpp",
    "$av_codec_root_dir/services/services/codec/server/video/post_processing/state_machine.cpp",
    "$av_codec_root_dir/services/services/codec/server/video/temporal_scalability.cpp",
    "$av_codec_root_dir/services/services/codeclist/ipc/codeclist_service_stub.cpp",
    "$av_codec_root_dir/services/services/codeclist/server/codeclist_server.cpp",
    "$av_codec_root_dir/services/services/sa_avcodec/ipc/codeclist_parcel.cpp",
    "$av_codec_root_dir/test/unittest/video_test/codeclist_test/capi/codeclist_capi_mock.cpp",
    "$av_codec_root_dir/test/unittest/video_test/codeclist_test/capi/codeclist_capi_mock_factory.cpp",
    "$event_handler_dir/background_event_handler/background_event_handler.cpp",
    "../vcodec_framework_test/common/utils/unittest_utils.cpp",
    "./codec_server_coverage_unit_test.cpp",
    "./mock/codec_drm_decrypt_mock.cpp",
    "./mock/codecbase_mock.cpp",
    "./post_processing_coverage_unit_test.cpp",
  ]

  # av_codec_engine_codeclist_mock
  sources += [
    "$av_codec_root_dir/services/engine/codeclist/codeclist_core.cpp",
    "./mock/codec_ability_singleton_mock.cpp",
  ]

  deps = [
    ":av_codec_engine_codeclist_mock",  # av_codec_engine_codeclist_mock
    "$av_codec_root_dir/interfaces/kits/c:capi_packages",
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
    "$av_codec_root_dir/services/services/codec/server/video/features/smart_fluency_decoding:smart_fluency_decoding",
    "$av_codec_root_dir/services/services/common/adaptive_framerate_controller:adaptive_framerate_controller",
    "$av_codec_root_dir/services/utils:av_codec_service_utils",
  ]

  external_deps = [
    "cJSON:cjson",
    "c_utils:utils",
    "config_policy:configpolicy_util",
    "eventhandler:libeventhandler",
    "googletest:gmock_main",
    "graphic_2d:libgraphic_utils",
    "graphic_2d:librender_service_base",
    "graphic_2d:librender_service_client",
    "graphic_surface:surface",
    "graphic_surface:sync_fence",
    "hilog:libhilog",
    "hisysevent:libhisysevent",
    "hiview:libucollection_client",
    "init:libbegetutil",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
    "resource_schedule_service:ressched_client",
    "samgr:samgr_proxy",
    "window_manager:libwm",
    "hiview:xperfservice_client",
  ]

  if (av_codec_support_drm) {
    external_deps += [
      "drm_framework:drm_framework",
      "drm_framework:native_drm",
    ]
  }

  resource_config_file =
      "$av_codec_root_dir/test/unittest/resources/ohos_test.xml"
}

# 目的：反复mock单例模式的初始化方法
# 作用：defines将CodecAbilitySingleton替换成Impl，在测试用例中继承Impl并重写GetInstance方法
ohos_static_library("av_codec_engine_codeclist_mock") {
  testonly = true
  cflags = av_codec_unittest_cflags
  cflags_cc = cflags
  defines = [ "CodecAbilitySingleton=CodecAbilitySingletonImpl" ]
  if (av_codec_enable_special_codec) {
    defines += [ "AV_CODEC_AUDIO_SPECIAL_CAPACITY" ]
  }
  if (target_cpu == "arm64") {
    av_codec_path = "\"/system/lib64\""
  } else {
    av_codec_path = "\"/system/lib\""
  }
  defines += [ "AV_CODEC_PATH=${av_codec_path}" ]
  sanitize = av_codec_sanitize
  include_dirs = codec_server_coverage_include_dirs

  sources = [
    "$av_codec_root_dir/services/engine/codeclist/audio_codeclist_info.cpp",
    "$av_codec_root_dir/services/engine/codeclist/codec_ability_singleton.cpp",
    "$av_codec_root_dir/services/engine/codeclist/codeclist_builder.cpp",
    "$av_codec_root_dir/services/media_engine/plugins/ffmpeg_adapter/common/hdi_codec.cpp",
  ]

  deps = [
    "$av_codec_root_dir/services/dfx:av_codec_service_dfx",
    "$av_codec_root_dir/services/utils:av_codec_service_utils",
  ]

  external_deps = [
    "c_utils:utils",
    "drivers_interface_codec:libcodec_proxy_4.0",
    "googletest:gmock_main",
    "graphic_surface:surface",
    "graphic_surface:sync_fence",
    "hilog:libhilog",
    "ipc:ipc_single",
    "media_foundation:media_foundation",
  ]
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

##################################################################################################################