# Copyright (c) 2025 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
# http://www.apache.org/licenses/LICENSE-2.0
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/config/components/ets_frontend/ets2abc_config.gni")
import("//build/ohos.gni")
import("//build/ohos/taihe_idl/taihe.gni")
import("//foundation/multimodalinput/input/multimodalinput_mini.gni")
copy_taihe_idl("pointer_taihe") {
  sources = [ "idl/ohos.multimodalInput.pointer.taihe" ]
  deps = [ "${mmi_path}/frameworks/ets/key_code:key_code_taihe" ]
}
config("pointer_config") {
  visibility = [ ":*" ]

  include_dirs = [
    "${mmi_path}/frameworks/ets/common/include",
    "${mmi_path}/util/common/include",
    "${mmi_path}/tools/event_inject/include",
    "${mmi_path}/interfaces/native/innerkits/proxy/include",
    "${mmi_path}/frameworks/ets/pointer/include"
  ]
}
subsystem_name = "multimodalinput"
part_name = "input"
taihe_generated_file_path_pointer =
    "$taihe_file_path/out/$subsystem_name/$part_name/pointer"
ohos_taihe("run_taihe") {
  taihe_generated_file_path = "${taihe_generated_file_path_pointer}"
  deps = [
    ":pointer_taihe",
    "${mmi_path}/frameworks/ets/key_code:key_code_taihe",
  ]
  outputs = [
    "$taihe_generated_file_path/src/ohos.multimodalInput.pointer.ani.cpp",
    "$taihe_generated_file_path/src/ohos.multimodalInput.pointer.abi.c",
  ]
}
taihe_shared_library("Pointer") {
  taihe_generated_file_path = "${taihe_generated_file_path_pointer}"
  part_name = "$part_name"
  subsystem_name = "$subsystem_name"
  sources = get_target_outputs(":run_taihe")
  configs = [
    "${mmi_path}:coverage_flags",
    ":pointer_config",
  ]
  external_deps = [
    "access_token:libaccesstoken_sdk",
    "access_token:libtokenid_sdk",
    "c_utils:utils",
    "hilog:libhilog",
    "image_framework:image_native",
    "image_framework:image_taihe",
    "ipc:ipc_single",
  ]
  if (input_feature_api_metrics_histogram) {
    external_deps += [ "api_metrics:histogrammanager" ]
  }
  sources += [
    "${mmi_path}/frameworks/ets/common/src/ani_common.cpp",
    "src/ani_constructor.cpp",
    "src/ohos.multimodalInput.pointer.impl.cpp",
    "src/taihe_pointer_utils.cpp",
  ]
  deps = [
    ":run_taihe",
    "${mmi_path}/frameworks/proxy:libmmi-client",
    "${mmi_path}/util:libmmi-util",
  ]
  branch_protector_ret = "pac_ret"
  sanitize = {
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
  }
}
generate_static_abc("pointer") {
  base_url = "${taihe_generated_file_path_pointer}"
  files = [
    "${taihe_generated_file_path_pointer}/@ohos.multimodalInput.pointer.ets",
  ]
  is_boot_abc = "True"
  device_dst_file = "/system/framework/pointer.abc"
  dependencies = [ ":run_taihe" ]
}
ohos_prebuilt_etc("pointer_etc") {
  source = "$target_out_dir/pointer.abc"
  module_install_dir = "framework"
  part_name = "$part_name"
  subsystem_name = "$subsystem_name"
  deps = [ ":pointer" ]
}

group("ets_pointer_package") {
  deps = [
    ":Pointer",
    ":pointer_etc",
  ]
}