# Copyright (C) 2024 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//build/test.gni")

rust_cxx("ffrt_rs_cxx_gen") {
  sources = [ "src/wrapper.rs" ]
}

ohos_static_library("ffrt_rs_cxx") {
  branch_protector_ret = "pac_ret"
  stack_protector_ret = true
  sanitize = {
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
  }

  include_dirs = [
    "include",
    "${target_gen_dir}/src",
  ]
  sources = [ "src/cxx/wrapper.cpp" ]

  sources += get_target_outputs(":ffrt_rs_cxx_gen")

  external_deps = [
    "ffrt:libffrt",
    "rust_cxx:cxx_cppdeps",
  ]
  deps = [ ":ffrt_rs_cxx_gen" ]

  subsystem_name = "request"
  part_name = "request"
}

ohos_rust_static_library("ffrt_rs") {
  sanitize = {
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
  }

  sources = [ "src/lib.rs" ]
  rustflags = [
    "-Copt-level=z",
    "-Clto=yes",
    "-Ccodegen-units=1",
  ]

  external_deps = [
    "ffrt:libffrt",
    "rust_cxx:lib",
  ]

  deps = [ ":ffrt_rs_cxx" ]

  subsystem_name = "request"
  part_name = "request"
}

ohos_rust_unittest("rust_ffrt_rs_ut_test") {
  module_out_path = "request/request/common"

  sources = [ "src/lib.rs" ]

  external_deps = []

  deps = [ ":ffrt_rs_cxx" ]
  external_deps = [
    "ffrt:libffrt",
    "rust_cxx:lib",
  ]

  subsystem_name = "request"
  part_name = "request"
}

group("unittest") {
  testonly = true
  deps = []
  if (!use_clang_coverage) {
    deps = [ ":rust_ffrt_rs_ut_test" ]
  }
}