# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//base/security/device_security_level/common/dslm.gni")
import("//build/ohos.gni")

declare_args() {
  device_security_level_feature_secondary_session_name = ""
}

# service_msg object
ohos_source_set("service_msg_obj") {
  sources = [ "dslm_messenger_wrapper.c" ]

  include_dirs = [
    "../../interfaces/inner_api/include",
    "../include",
  ]

  deps = [
    "../../baselib/msglib:messenger_static",
    "../../baselib/utils:utils_static",
  ]

  if (defined(ohos_lite)) {
    if (ohos_kernel_type == "linux" || ohos_kernel_type == "liteos_a") {
      deps += [ "$dslm_hilog_path/featured:hilog_shared" ]
    } else if (ohos_kernel_type == "liteos_m") {
      deps += [ "$dslm_hilog_path/featured:hilog_static" ]
    }
  } else {
    sanitize = {
      integer_overflow = true
      ubsan = true
      boundary_sanitize = true
      cfi = true
      cfi_cross_dso = true
      blocklist = "../../cfi_blocklist.txt"
    }
    branch_protector_ret = "pac_ret"

    external_deps = [
      "c_utils:utils",
      "hilog:libhilog",
    ]
  }

  if (device_security_level_feature_secondary_session_name != "") {
    defines = [ "SECONDARY_SOCKET_NAME=\"${device_security_level_feature_secondary_session_name}\"" ]
  }

  configs = [ "../../common:common_configs" ]

  part_name = "device_security_level"
  subsystem_name = "security"
}