# Copyright (c) 2021-2025 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("../windowmanager_aafwk.gni")
config("libwmutil_private_config") {
  include_dirs = [
    "include",
    "../dmserver/include",
    "../interfaces/innerkits/dm",
    "../interfaces/innerkits/wm",
    "${window_base_path}/wm/include",
    "${window_base_path}/window_scene/common/include",
  ]
}

config("libwmutil_public_config") {
  include_dirs = [
    "include",
    "${window_base_path}/window_scene/interfaces/include",
    "../interfaces/innerkits/dm",
    "../interfaces/innerkits/wm",
    "../interfaces/kits/ndk/wm",
  ]
}

ohos_source_set("ui_effect_controller_common") {
  branch_protector_ret = "pac_ret"
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    cfi_vcall_icall_only = true
    debug = false
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
    cfi_policy = "adaptive"
  }

  sources = [
    "src/ui_effect_controller_common.cpp",
  ]

  public_configs = [
    ":libwmutil_public_config",
  ]

  deps = [
    ":libwmutil_base",
  ]

  external_deps = [
    "ability_runtime:runtime",
    "c_utils:utils",
    "graphic_2d:librender_service_client",
    "hilog:libhilog",
    "napi:ace_napi",
    "node:node_header_notice",
    "libuv:uv",
  ]
  part_name = "window_manager"
  subsystem_name = "window"
}

wmutil_sources = [
  "src/collaborator_dll_manager.cpp",
  "src/dm_virtual_screen_option.cpp",
  "src/dms_reporter.cpp",
  "src/dms_xcollie.cpp",
  "src/ffrt_queue_helper.cpp",
  "src/ffrt_serial_queue_helper.cpp",
  "src/floating_ball_report.cpp",
  "src/floating_view_report.cpp",
  "src/perform_reporter.cpp",
  "src/permission.cpp",
  "src/persistent_storage.cpp",
  "src/pip_report.cpp",
  "src/rs_adapter.cpp",
  "src/screen_fold_data.cpp",
  "src/screen_group_info.cpp",
  "src/screen_info.cpp",
  "src/surface_draw.cpp",
  "src/surface_reader.cpp",
  "src/surface_reader_handler_impl.cpp",
  "src/sys_cap_util.cpp",
  "src/task_sequence_process.cpp",
  "src/typec_port_info.cpp",
  "src/vsync_station.cpp",
  "src/window_frame_trace_impl.cpp",
  "src/window_property.cpp",
  "src/window_transition_info.cpp",
]

wmutil_external_deps = [
  "ability_base:want",
  "ability_runtime:ability_manager",
  "ability_runtime:ability_start_setting",
  "ability_runtime:wantagent_innerkits",
  "access_token:libaccesstoken_sdk",
  "access_token:libtokenid_sdk",
  "bundle_framework:appexecfwk_base",
  "bundle_framework:appexecfwk_core",
  "c_utils:utils",
  "eventhandler:libeventhandler",
  "ffrt:libffrt",
  "graphic_2d:2d_graphics",
  "graphic_2d:librender_service_base",
  "graphic_2d:librender_service_client",
  "graphic_surface:surface",
  "hicollie:libhicollie",
  "hilog:libhilog",
  "hisysevent:libhisysevent",
  "hitrace:hitrace_meter",
  "image_framework:image_native",
  "init:libbegetutil",
  "input:libmmi-client",
  "ipc:ipc_single",
  "preferences:native_preferences",
  "samgr:samgr_proxy",
]

## build libwmutil_static.a
ohos_static_library("libwmutil_static") {
  branch_protector_ret = "pac_ret"
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    cfi_vcall_icall_only = true
    debug = false
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
  }
  sources = wmutil_sources
  sources += [
    "src/accessibility_window_info.cpp",
    "src/agent_death_recipient.cpp",
    "src/color_parser.cpp",
    "src/cutout_info.cpp",
    "src/display_change_info.cpp",
    "src/display_info.cpp",
    "src/screenshot_info.cpp",
    "src/singleton_container.cpp",
    "src/string_util.cpp",
    "src/unreliable_window_info.cpp",
    "src/window_drawing_content_info.cpp",
    "src/window_visibility_info.cpp",
    "src/wm_math.cpp",
    "src/wm_occlusion_region.cpp",
    "src/xml_config_base.cpp",
  ]

  configs = [
    ":libwmutil_private_config",
    "${window_base_path}/resources/config/build:coverage_flags",
  ]

  public_configs = [ ":libwmutil_public_config" ]

  deps = [ ":libwmutil_base" ]

  external_deps = wmutil_external_deps

  part_name = "window_manager"
  subsystem_name = "window"

  defines = []
  defines += [ "FRAME_TRACE_ENABLE" ]
  external_deps += [ "frame_aware_sched:frame_trace_intf" ]
}

## Build libwmutil_base.so
ohos_shared_library("libwmutil_base") {
  branch_protector_ret = "pac_ret"
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    cfi_vcall_icall_only = true
    debug = false
    cfi_policy = "adaptive"
  }
  sources = [
    "src/accessibility_window_info.cpp",
    "src/agent_death_recipient.cpp",
    "src/color_parser.cpp",
    "src/cutout_info.cpp",
    "src/display_change_info.cpp",
    "src/display_info.cpp",
    "src/dm_common.cpp",
    "src/dms_global_mutex.cpp",
    "src/load_mmi_client_adapter.cpp",
    "src/rate_limited_logger.cpp",
    "src/screen_group_info.cpp",
    "src/screen_info.cpp",
    "src/screenshot_info.cpp",
    "src/singleton_container.cpp",
    "src/string_util.cpp",
    "src/unreliable_window_info.cpp",
    "src/window_drawing_content_info.cpp",
    "src/window_error_msg.cpp",
    "src/window_manager_hilog.cpp",
    "src/window_pid_visibility_info.cpp",
    "src/window_visibility_info.cpp",
    "src/wm_common.cpp",
    "src/wm_math.cpp",
    "src/wm_occlusion_region.cpp",
    "src/xml_config_base.cpp",
  ]

  configs = [ ":libwmutil_private_config" ]

  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
    "ipc:ipc_single",
    "init:libbegetutil",
  ]

  ldflags = [ "-Wl,-Bsymbolic-functions" ]
  innerapi_tags = [ "platformsdk" ]
  part_name = "window_manager"
  subsystem_name = "window"
}

## Build libwmutil.so
ohos_shared_library("libwmutil") {
  branch_protector_ret = "pac_ret"
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    cfi_vcall_icall_only = true
    debug = false
    cfi_policy = "adaptive"
  }
  sources = wmutil_sources

  configs = [
    ":libwmutil_private_config",
    "../resources/config/build:coverage_flags",
  ]

  public_configs = [ ":libwmutil_public_config" ]

  deps = [ ":libwmutil_base" ]

  external_deps = wmutil_external_deps
  if (!(host_os == "linux" && host_cpu == "arm64")) {
    external_deps += [ "preferences:native_preferences" ]
  }
  ldflags = [ "-Wl,-Bsymbolic-functions" ]

  innerapi_tags = [ "platformsdk" ]
  part_name = "window_manager"
  subsystem_name = "window"
  if (is_ohos && is_clang && target_cpu == "arm64") {
    ldflags += [
        "-Wl,--emit-relocs",
        "-Wl,--no-relax",
        "-mno-fix-cortex-a53-843419"
    ]
  }

  defines = []
  if (build_variant == "user") {
    defines += [ "IS_RELEASE_VERSION" ]
  }

  defines += [ "FRAME_TRACE_ENABLE" ]
  external_deps += [ "frame_aware_sched:frame_trace_intf" ]
  version_script = "libwmutil.map"
}

group("test") {
  testonly = true
  deps = [ "test:test" ]
}