# ArkUI3 SDK producer entry points — thin wrappers over arktsx/sdk/sdk.mjs.
# Build configuration lives in arktsx/sdk/sdk.yml (platforms, artifact targets,
# copy filters, package allowlist, nexus endpoints).

# Show available recipes.
default:
    @just --list

sdk := "node arktsx/sdk/sdk.mjs"
host_os := if `uname -s` == "Darwin" { "macos" } else { "linux" }

# Full pipeline: setup + compile:ohos + assemble the SDK tree.
# `just build linux` / `just build windows` / `just build macos`
build platform=host_os *flags:
    {{sdk}} build {{platform}} {{flags}}

# Re-assemble the SDK tree from the built checkout (CI-style).
assemble platform=host_os *flags:
    {{sdk}} assemble {{platform}} {{flags}}

# Zip the assembled SDK directory.
archive platform=host_os *flags:
    {{sdk}} archive {{platform}} {{flags}}

# Publish the zip to Nexus (OPENLAB_USERNAME / OPENLAB_PASSWORD required).
# Set force=1 to overwrite an existing version.
publish platform=host_os force='':
    {{sdk}} publish {{platform}}{{ if force != '' { " --force" } else { "" } }}

# Bump the SDK patch version (arktsx/sdk/cli/package.json), double-bump guarded.
bump-version:
    {{sdk}} bump-version