package model_context_protocol.client

import stdx.encoding.json.*
import model_context_protocol.protocol.ProgressToken

// Per-request options mirroring RequestOptions in the C# SDK.
public class RequestOptions {
    private let _meta: ?JsonObject
    private let _progressToken: ?ProgressToken
    private let _timeout: ?Duration

    public init(meta!: ?JsonObject = None, progressToken!: ?ProgressToken = None,
        timeout!: ?Duration = None) {
        if (let Some(value) <- timeout) {
            if (value <= Duration.Zero) {
                throw IllegalArgumentException("Request timeout must be positive")
            }
        }
        _meta = meta
        _progressToken = progressToken
        _timeout = timeout
    }

    public prop meta: ?JsonObject {
        get() {
            _meta
        }
    }

    public prop progressToken: ?ProgressToken {
        get() {
            _progressToken
        }
    }

    public prop timeout: ?Duration {
        get() {
            _timeout
        }
    }

    // Returns a copy of the user metadata with the progress token applied.
    public func getMetaForRequest(): JsonObject {
        let result = JsonObject()
        if (let Some(metadata) <- _meta) {
            for ((name, value) in metadata.getFields()) {
                result.put(name, value)
            }
        }
        if (let Some(token) <- _progressToken) {
            result.put("progressToken", progressTokenJson(token))
        }
        result
    }
}

private func progressTokenJson(token: ProgressToken): JsonValue {
    match (token) {
        case ProgressToken.StringToken(value) => JsonString(value)
        case ProgressToken.IntegerToken(value) => JsonInt(value)
    }
}